[Flex]Drag&Dropは俺にきいてくれ

<?xml version="1.0" encoding="utf-8"?>
<mx:List xmlns:mx="http://www.adobe.com/2006/mxml"
    dragEnabled="true" dropEnabled="true" dragMoveEnabled="true">
    <mx:itemRenderer>
        <mx:Component>
            <mx:HBox backgroundColor="#111111" horizontalScrollPolicy="off">
                <mx:Script><![CDATA[
                    public function rowNum(item:Object):String {
                        var i:int = outerDocument.dataProvider.getItemIndex(item) + 1;
                        return String(i);
                    }
 
                    public function getName(item:Object):String {
                        return item.@name.toString();
                    }
                ]]></mx:Script>
                <mx:Label text="{rowNum(data)}" width="25" textAlign="right" />
                <mx:Label text="{getName(data)}" />
            </mx:HBox>
        </mx:Component>
    </mx:itemRenderer>
    <mx:Script><![CDATA[
        import mx.managers.DragManager;
        import mx.events.DragEvent;
 
        private function checkDragEvent(event:DragEvent):Boolean {
            if (event.dragSource.hasFormat("items")) {
                var items:Array = event.dragSource.dataForFormat('items') as Array;
                return (typeof(items[0]) == "xml" && items[0].name() == "item");
            }
            return false;
        }
 
        override protected function dragEnterHandler(event:DragEvent):void {
            if (checkDragEvent(event)) {
                if (event.dragInitiator is MediaSelector) {
                    super.dragEnterHandler(event);
                    return;
                }
            }
            DragManager.showFeedback(DragManager.NONE);
        }
 
        override protected function dragDropHandler(event:DragEvent):void {
            trace("drag&drop mediaselector" + typeof(event.currentTarget));
            super.dragDropHandler(event);
        }
 
        override protected function dragCompleteHandler(event:DragEvent):void {
            trace("drag complete " + event);
            if (event.relatedObject is MediaSelector) {
                super.dragCompleteHandler(event);
                return;
            }
            trace("drag complete not media-selector");
            event.preventDefault();
        } 
    ]]></mx:Script>
</mx:List>

<?xml version="1.0" encoding="utf-8"?>
<mx:List xmlns:mx="http://www.adobe.com/2006/mxml"
    dragEnabled="true" dropEnabled="true" dragMoveEnabled="true">
    <mx:Script><![CDATA[
        public var mediaList:XMLList;
    ]]></mx:Script>
    <mx:itemRenderer>
        <mx:Component>
            <mx:HBox backgroundColor="#111111" horizontalScrollPolicy="off">
                <mx:Script><![CDATA[
                    public function rowNum(item:Object):String {
                        var i:int = outerDocument.dataProvider.getItemIndex(item) + 1;
                        return String(i);
                    }
 
                    public function getName(item:Object):String {
                        var media:XMLList = outerDocument.mediaList.item.(@id == item.text().toString());
                        if (media) {
                            return media.@name.toString();
                        }
                        return "(not found id:" + item.text().toString() + ")";
                    }
 
                    public function getTransition(item:Object):String {
                        var transition:String = item.@transition.toString();
                        return transition;
                    }
 
                    public function getNext(item:Object):String {
                        var next:String = item.@next.toString();
                        return next;
                    }
                ]]></mx:Script>
                <mx:Label text="{rowNum(data)}" width="20" textAlign="right" />
                <mx:Label text="{getName(data)}" width="300" />
                <mx:Label text="{getTransition(data)}" width="50" />
                <mx:Label text="{getNext(data)}" width="50" />
            </mx:HBox>
        </mx:Component>
    </mx:itemRenderer>
    <mx:Script><![CDATA[
        import mx.managers.DragManager;
        import mx.events.DragEvent;
 
        private function checkDragEvent(event:DragEvent):Boolean {
            if (event.dragSource.hasFormat("items")) {
                var items:Array = event.dragSource.dataForFormat('items') as Array;
                return (typeof(items[0]) == "xml" && items[0].name() == "item");
            }
            return false;
        }
 
        override protected function dragEnterHandler(event:DragEvent):void {
            if (checkDragEvent(event)) {
                super.dragEnterHandler(event);
            } else {
                DragManager.showFeedback(DragManager.NONE);
            }
        }
 
        override protected function dragDropHandler(event:DragEvent):void {
            if (event.dragInitiator is PlaylistEditor) {
                // 同じクラスからの場合はリストの入替えとする
                super.dragDropHandler(event);
                return;
            }
 
            // アイテム追加
            var items:Array = event.dragSource.dataForFormat('items') as Array;
            var data:XML = <item />;
            data.setChildren(items[0].@id.toString());
            trace(data);
 
            var list:List = List(event.currentTarget);
            var pos:int = list.calculateDropIndex(event);
            list.dataProvider.addItemAt(data, pos);
            event.preventDefault();
            hideDropFeedback(event);
        }
 
        override protected function dragCompleteHandler(event:DragEvent):void {
            super.dragCompleteHandler(event);
        } 
    ]]></mx:Script>
</mx:List>